perlre - Perl regular expressions
This page describes the syntax of regular expressions in Perl.
If you haven't used regular expressions before, a quick-start
introduction is available in the perlrequick manpage, and a longer tutorial
introduction is available in the perlretut manpage.
For reference on how regular expressions are used in matching
operations, plus various examples of the same, see discussions of
m//, s///, qr// and ?? in Regexp Quote-Like Operators in the perlop manpage.
Matching operations can have various modifiers. Modifiers
that relate to the interpretation of the regular expression inside
are listed below. Modifiers that alter the way a regular expression
is used by Perl are detailed in Regexp Quote-Like Operators in the perlop manpage and
Gory details of parsing quoted constructs in the perlop manpage.
- m
-
Treat string as multiple lines. That is, change "^" and "$" from matching
the start or end of the string to matching the start or end of any
line anywhere within the string.
- s
-
Treat string as single line. That is, change "." to match any character
whatsoever, even a newline, which normally it would not match.
The /s and /m modifiers both override the $* setting. That
is, no matter what $* contains, /s without /m will force
"^" to match only at the beginning of the string and "$" to match
only at the end (or just before a newline at the end) of the string.
Together, as /ms, they let the "." match any character whatsoever,
while still allowing "^" and "$" to match, respectively, just after
and just before newlines within the string.
- i
-
Do case-insensitive pattern matching.
If use locale is in effect, the case map is taken from the current
locale. See the perllocale manpage.
- x
-
Extend your pattern's legibility by permitting whitespace and comments.
- p
-
Preserve the string matched such that ${^PREMATCH}, {$^MATCH}, and
${^POSTMATCH} are available for use after matching.
- g and c
-
Global matching, and keep the Current position after failed matching.
Unlike i, m, s and x, these two flags affect the way the regex is used
rather than the regex itself. See
Using regular expressions in Perl in the perlretut manpage for further explanation
of the g and c modifiers.
These are usually written as "the /x modifier", even though the delimiter
in question might not really be a slash. Any of these
modifiers may also be embedded within the regular expression itself using
the (?...) construct. See below.
The /x modifier itself needs a little more explanation. It tells
the regular expression parser to ignore whitespace that is neither
backslashed nor within a character class. You can use this to break up
your regular expression into (slightly) more readable parts. The #
character is also treated as a metacharacter introducing a comment,
just as in ordinary Perl code. This also means that if you want real
whitespace or # characters in the pattern (outside a character
class, where they are unaffected by /x), then you'll either have to
escape them (using backslashes or \Q...\E) or encode them using octal
or hex escapes. Taken together, these features go a long way towards
making Perl's regular expressions more readable. Note that you have to
be careful not to include the pattern delimiter in the comment--perl has
no way of knowing you did not intend to close the pattern early. See
the C-comment deletion code in the perlop manpage. Also note that anything inside
a \Q...\E stays unaffected by /x.
The patterns used in Perl pattern matching evolved from those supplied in
the Version 8 regex routines. (The routines are derived
(distantly) from Henry Spencer's freely redistributable reimplementation
of the V8 routines.) See Version 8 Regular Expressions for
details.
In particular the following metacharacters have their standard egrep-ish
meanings:
\ Quote the next metacharacter
^ Match the beginning of the line
. Match any character (except newline)
$ Match the end of the line (or before newline at the end)
| Alternation
() Grouping
[] Character class
By default, the "^" character is guaranteed to match only the
beginning of the string, the "$" character only the end (or before the
newline at the end), and Perl does certain optimizations with the
assumption that the string contains only one line. Embedded newlines
will not be matched by "^" or "$". You may, however, wish to treat a
string as a multi-line buffer, such that the "^" will match after any
newline within the string (except if the newline is the last character in
the string), and "$" will match before any newline. At the
cost of a little more overhead, you can do this by using the /m modifier
on the pattern match operator. (Older programs did this by setting $*,
but this practice is now deprecated.)
To simplify multi-line substitutions, the "." character never matches a
newline unless you use the /s modifier, which in effect tells Perl to pretend
the string is a single line--even if it isn't. The /s modifier also
overrides the setting of $*, in case you have some (badly behaved) older
code that sets it in another module.
The following standard quantifiers are recognized:
* Match 0 or more times
+ Match 1 or more times
? Match 1 or 0 times
{n} Match exactly n times
{n,} Match at least n times
{n,m} Match at least n but not more than m times
(If a curly bracket occurs in any other context, it is treated
as a regular character. In particular, the lower bound
is not optional.) The "*" quantifier is equivalent to {0,}, the "+"
quantifier to {1,}, and the "?" quantifier to {0,1}. n and m are limited
to integral values less than a preset limit defined when perl is built.
This is usually 32766 on the most common platforms. The actual limit can
be seen in the error message generated by code such as this:
$_ **= $_ , / {$_} / for 2 .. 42;
By default, a quantified subpattern is "greedy", that is, it will match as
many times as possible (given a particular starting location) while still
allowing the rest of the pattern to match. If you want it to match the
minimum number of times possible, follow the quantifier with a "?". Note
that the meanings don't change, just the "greediness":
*? Match 0 or more times, not greedily
+? Match 1 or more times, not greedily
?? Match 0 or 1 time, not greedily
{n}? Match exactly n times, not greedily
{n,}? Match at least n times, not greedily
{n,m}? Match at least n but not more than m times, not greedily
Because patterns are processed as double quoted strings, the following
also work:
\t tab (HT, TAB)
\n newline (LF, NL)
\r return (CR)
\f form feed (FF)
\a alarm (bell) (BEL)
\e escape (think troff) (ESC)
\033 octal char (example: ESC)
\x1B hex char (example: ESC)
\x{263a} long hex char (example: Unicode SMILEY)
\cK control char (example: VT)
\N{name} named Unicode character
\l lowercase next char (think vi)
\u uppercase next char (think vi)
\L lowercase till \E (think vi)
\U uppercase till \E (think vi)
\E end case modification (think vi)
\Q quote (disable) pattern metacharacters till \E
If use locale is in effect, the case map used by \l, \L, \u
and \U is taken from the current locale. See the perllocale manpage. For
documentation of \N{name}, see the charnames manpage.
You cannot include a literal $ or @ within a \Q sequence.
An unescaped $ or @ interpolates the corresponding variable,
while escaping will cause the literal string \$ to be matched.
You'll need to write something like m/\Quser\E\@\Qhost/.
In addition, Perl defines the following:
\w Match a "word" character (alphanumeric plus "_")
\W Match a non-"word" character
\s Match a whitespace character
\S Match a non-whitespace character
\d Match a digit character
\D Match a non-digit character
\pP Match P, named property. Use \p{Prop} for longer names.
\PP Match non-P
\X Match eXtended Unicode "combining character sequence",
equivalent to (?>\PM\pM*)
\C Match a single C char (octet) even under Unicode.
NOTE: breaks up characters into their UTF-8 bytes,
so you may end up with malformed pieces of UTF-8.
Unsupported in lookbehind.
A \w matches a single alphanumeric character (an alphabetic
character, or a decimal digit) or _, not a whole word. Use \w+
to match a string of Perl-identifier characters (which isn't the same
as matching an English word). If use locale is in effect, the list
of alphabetic characters generated by \w is taken from the current
locale. See the perllocale manpage. You may use \w, \W, \s, \S,
\d, and \D within character classes, but they aren't usable
as either end of a range. If any of them precedes or follows a "-",
the "-" is understood literally. If Unicode is in effect, \s matches
also "\x{85}", "\x{2028}, and "\x{2029}". See the perlunicode manpage for more
details about \pP, \PP, \X and the possibility of defining
your own \p and \P properties, and the perluniintro manpage about Unicode
in general.
The POSIX character class syntax
[:class:]
is also available. Note that the [ and ] brackets are literal;
they must always be used within a character class expression.
$string =~ /[[:alpha:]]/;
$string =~ /[:alpha:]/;
The available classes and their backslash equivalents (if available) are
as follows:
alpha
alnum
ascii
blank [1]
cntrl
digit \d
graph
lower
print
punct
space \s [2]
upper
word \w [3]
xdigit
- [1]
-
A GNU extension equivalent to [ \t], "all horizontal whitespace".
- [2]
-
Not exactly equivalent to \s since the [[:space:]] includes
also the (very rare) "vertical tabulator", "\cK" or chr(11) in ASCII.
- [3]
-
A Perl extension, see above.
For example use [:upper:] to match all the uppercase characters.
Note that the [] are part of the [::] construct, not part of the
whole character class. For example:
[01[:alpha:]%]
matches zero, one, any alphabetic character, and the percent sign.
The following equivalences to Unicode \p{} constructs and equivalent
backslash character classes (if available), will hold:
[[:...:]] \p{...} backslash
alpha IsAlpha
alnum IsAlnum
ascii IsASCII
blank
cntrl IsCntrl
digit IsDigit \d
graph IsGraph
lower IsLower
print IsPrint
punct IsPunct
space IsSpace
IsSpacePerl \s
upper IsUpper
word IsWord
xdigit IsXDigit
For example [[:lower:]] and \p{IsLower} are equivalent.
If the utf8 pragma is not used but the locale pragma is, the
classes correlate with the usual isalpha(3) interface (except for
"word" and "blank").
The other named classes are:
- cntrl
-
Any control character. Usually characters that don't produce output as
such but instead control the terminal somehow: for example newline and
backspace are control characters. All characters with ord() less than
32 are usually classified as control characters (assuming ASCII,
the ISO Latin character sets, and Unicode), as is the character with
the ord() value of 127 (DEL).
- graph
-
Any alphanumeric or punctuation (special) character.
- print
-
Any alphanumeric or punctuation (special) character or the space character.
- punct
-
Any punctuation (special) character.
- xdigit
-
Any hexadecimal digit. Though this may feel silly ([0-9A-Fa-f] would
work just fine) it is included for completeness.
You can negate the [::] character classes by prefixing the class name
with a '^'. This is a Perl extension. For example:
POSIX traditional Unicode
[[:^digit:]] \D \P{IsDigit}
[[:^space:]] \S \P{IsSpace}
[[:^word:]] \W \P{IsWord}
Perl respects the POSIX standard in that POSIX character classes are
only supported within a character class. The POSIX character classes
[.cc.] and [=cc=] are recognized but not supported and trying to
use them will cause an error.
Perl defines the following zero-width assertions:
\b Match a word boundary
\B Match except at a word boundary
\A Match only at beginning of string
\Z Match only at end of string, or before newline at the end
\z Match only at end of string
\G Match only at pos() (e.g. at the end-of-match position
of prior m//g)
A word boundary (\b) is a spot between two characters
that has a \w on one side of it and a \W on the other side
of it (in either order), counting the imaginary characters off the
beginning and end of the string as matching a \W. (Within
character classes \b represents backspace rather than a word
boundary, just as it normally does in any double-quoted string.)
The \A and \Z are just like "^" and "$", except that they
won't match multiple times when the /m modifier is used, while
"^" and "$" will match at every internal line boundary. To match
the actual end of the string and not ignore an optional trailing
newline, use \z.
The \G assertion can be used to chain global matches (using
m//g), as described in Regexp Quote-Like Operators in the perlop manpage.
It is also useful when writing lex-like scanners, when you have
several patterns that you want to match against consequent substrings
of your string, see the previous reference. The actual location
where \G will match can also be influenced by using pos() as
an lvalue: see pos in the perlfunc manpage. Currently \G is only fully
supported when anchored to the start of the pattern; while it
is permitted to use it elsewhere, as in /(?<=\G..)./g, some
such uses (/.\G/g, for example) currently cause problems, and
it is recommended that you avoid such usage for now.
The bracketing construct ( ... ) creates capture buffers. To refer
to the current contents of a buffer later on, within the same pattern,
use \1 for the first, \2 for the second, and so on.
Outside the match use "$" instead of "\". (The
\<digit> notation works in certain circumstances outside
the match. See the warning below about \1 vs $1 for details.)
Referring back to another part of the match is called a
backreference.
There is no limit to the number of captured substrings that you may
use. However Perl also uses \10, \11, etc. as aliases for \010,
\011, etc. (Recall that 0 means octal, so \011 is the character at
number 9 in your coded character set; which would be the 10th character,
a horizontal tab under ASCII.) Perl resolves this
ambiguity by interpreting \10 as a backreference only if at least 10
left parentheses have opened before it. Likewise \11 is a
backreference only if at least 11 left parentheses have opened
before it. And so on. \1 through \9 are always interpreted as
backreferences.
Examples:
s/^([^ ]*) *([^ ]*)/$2 $1/;
if (/(.)\1/) {
print "'$1' is the first doubled character\n";
}
if (/Time: (..):(..):(..)/) {
$hours = $1;
$minutes = $2;
$seconds = $3;
}
Several special variables also refer back to portions of the previous
match. $+ returns whatever the last bracket match matched.
$& returns the entire matched string. (At one point $0 did
also, but now it returns the name of the program.) $` returns
everything before the matched string. $' returns everything
after the matched string. And $^N contains whatever was matched by
the most-recently closed group (submatch). $^N can be used in
extended patterns (see below), for example to assign a submatch to a
variable.
The numbered match variables ($1, $2, $3, etc.) and the related punctuation
set ($+, $&, $`, $', and $^N) are all dynamically scoped
until the end of the enclosing block or until the next successful
match, whichever comes first. (See Compound Statements in the perlsyn manpage.)
NOTE: Failed matches in Perl do not reset the match variables,
which makes it easier to write code that tests for a series of more
specific cases and remembers the best match.
WARNING: Once Perl sees that you need one of $&, $`, or
$' anywhere in the program, it has to provide them for every
pattern match. This may substantially slow your program. Perl
uses the same mechanism to produce $1, $2, etc, so you also pay a
price for each pattern that contains capturing parentheses. (To
avoid this cost while retaining the grouping behaviour, use the
extended regular expression (?: ... ) instead.) But if you never
use $&, $` or $', then patterns without capturing
parentheses will not be penalized. So avoid $&, $', and $`
if you can, but if you can't (and some algorithms really appreciate
them), once you've used them once, use them at will, because you've
already paid the price. As of 5.005, $& is not so costly as the
other two.
Backslashed metacharacters in Perl are alphanumeric, such as \b,
\w, \n. Unlike some other regular expression languages, there
are no backslashed symbols that aren't alphanumeric. So anything
that looks like \\, \(, \), \<, \>, \{, or \} is always
interpreted as a literal character, not a metacharacter. This was
once used in a common idiom to disable or quote the special meanings
of regular expression metacharacters in a string that you want to
use for a pattern. Simply quote all non-"word" characters:
$pattern =~ s/(\W)/\\$1/g;
(If use locale is set, then this depends on the current locale.)
Today it is more common to use the quotemeta() function or the \Q
metaquoting escape sequence to disable all metacharacters' special
meanings like this:
/$unquoted\Q$quoted\E$unquoted/
Beware that if you put literal backslashes (those not inside
interpolated variables) between \Q and \E, double-quotish
backslash interpolation may lead to confusing results. If you
need to use literal backslashes within \Q...\E,
consult Gory details of parsing quoted constructs in the perlop manpage.
Perl also defines a consistent extension syntax for features not
found in standard tools like awk and lex. The syntax is a
pair of parentheses with a question mark as the first thing within
the parentheses. The character after the question mark indicates
the extension.
The stability of these extensions varies widely. Some have been
part of the core language for many years. Others are experimental
and may change without warning or be completely removed. Check
the documentation on an individual feature to verify its current
status.
A question mark was chosen for this and for the minimal-matching
construct because 1) question marks are rare in older regular
expressions, and 2) whenever you see one, you should stop and
"question" exactly what is going on. That's psychology...
(?#text)-
A comment. The text is ignored. If the /x modifier enables
whitespace formatting, a simple # will suffice. Note that Perl closes
the comment as soon as it sees a ), so there is no way to put a literal
) in the comment.
(?imsx-imsx)-
One or more embedded pattern-match modifiers, to be turned on (or
turned off, if preceded by -) for the remainder of the pattern or
the remainder of the enclosing pattern group (if any). This is
particularly useful for dynamic patterns, such as those read in from a
configuration file, taken from an argument, or specified in a table
somewhere. Consider the case where some patterns want to be case
sensitive and some do not: The case insensitive ones merely need to
include (?i) at the front of the pattern. For example:
$pattern = "foobar";
if ( /$pattern/i ) { }
$pattern = "(?i)foobar";
if ( /$pattern/ ) { }
These modifiers are restored at the end of the enclosing group. For example,
( (?i) blah ) \s+ \1
will match blah in any case, some spaces, and an exact (including the case!)
repetition of the previous word, assuming the /x modifier, and no /i
modifier outside this group.
(?:pattern)(?imsx-imsx:pattern)-
This is for clustering, not capturing; it groups subexpressions like
"()", but doesn't make backreferences as "()" does. So
@fields = split(/\b(?:a|b|c)\b/)
is like
@fields = split(/\b(a|b|c)\b/)
but doesn't spit out extra fields. It's also cheaper not to capture
characters if you don't need to.
Any letters between ? and : act as flags modifiers as with
(?imsx-imsx). For example,
/(?s-i:more.*than).*million/i
is equivalent to the more verbose
/(?:(?s-i)more.*than).*million/i
(?=pattern)-
A zero-width positive look-ahead assertion. For example, /\w+(?=\t)/
matches a word followed by a tab, without including the tab in $&.
(?!pattern)-
A zero-width negative look-ahead assertion. For example /foo(?!bar)/
matches any occurrence of "foo" that isn't followed by "bar". Note
however that look-ahead and look-behind are NOT the same thing. You cannot
use this for look-behind.
If you are looking for a "bar" that isn't preceded by a "foo", /(?!foo)bar/
will not do what you want. That's because the (?!foo) is just saying that
the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
match. You would have to do something like /(?!foo)...bar/ for that. We
say "like" because there's the case of your "bar" not having three characters
before it. You could cover that this way: /(?:(?!foo)...|^.{0,2})bar/.
Sometimes it's still easier just to say:
if (/bar/ && $` !~ /foo$/)
For look-behind see below.
(?<=pattern)-
A zero-width positive look-behind assertion. For example, /(?<=\t)\w+/
matches a word that follows a tab, without including the tab in $&.
Works only for fixed-width look-behind.
(?<!pattern)-
A zero-width negative look-behind assertion. For example /(?<!bar)foo/
matches any occurrence of "foo" that does not follow "bar". Works
only for fixed-width look-behind.
(?{ code })-
WARNING: This extended regular expression feature is considered
highly experimental, and may be changed or deleted without notice.
This zero-width assertion evaluates any embedded Perl code. It
always succeeds, and its code is not interpolated. Currently,
the rules to determine where the code ends are somewhat convoluted.
This feature can be used together with the special variable $^N to
capture the results of submatches in variables without having to keep
track of the number of nested parentheses. For example:
$_ = "The brown fox jumps over the lazy dog";
/the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
print "color = $color, animal = $animal\n";
Inside the (?{...}) block, $_ refers to the string the regular
expression is matching against. You can also use pos() to know what is
the current position of matching within this string.
The code is properly scoped in the following sense: If the assertion
is backtracked (compare Backtracking), all changes introduced after
localization are undone, so that
$_ = 'a' x 8;
m<
(?{ $cnt = 0 }) # Initialize $cnt.
(
a
(?{
local $cnt = $cnt + 1; # Update $cnt, backtracking-safe.
})
)*
aaaa
(?{ $res = $cnt }) # On success copy to non-localized
# location.
>x;
will set $res = 4. Note that after the match, $cnt returns to the globally
introduced value, because the scopes that restrict local operators
are unwound.
This assertion may be used as a (?(condition)yes-pattern|no-pattern)
switch. If not used in this way, the result of evaluation of
code is put into the special variable $^R. This happens
immediately, so $^R can be used from other (?{ code }) assertions
inside the same regular expression.
The assignment to $^R above is properly localized, so the old
value of $^R is restored if the assertion is backtracked; compare
Backtracking.
Due to an unfortunate implementation issue, the Perl code contained in these
blocks is treated as a compile time closure that can have seemingly bizarre
consequences when used with lexically scoped variables inside of subroutines
or loops. There are various workarounds for this, including simply using
global variables instead. If you are using this construct and strange results
occur then check for the use of lexically scoped variables.
For reasons of security, this construct is forbidden if the regular
expression involves run-time interpolation of variables, unless the
perilous use re 'eval' pragma has been used (see the re manpage), or the
variables contain results of qr// operator (see
qr/STRING/imosx in the perlop manpage).
This restriction is due to the wide-spread and remarkably convenient
custom of using run-time determined strings as patterns. For example:
$re = <>;
chomp $re;
$string =~ /$re/;
Before Perl knew how to execute interpolated code within a pattern,
this operation was completely safe from a security point of view,
although it could raise an exception from an illegal pattern. If
you turn on the use re 'eval', though, it is no longer secure,
so you should only do so if you are also using taint checking.
Better yet, use the carefully constrained evaluation within a Safe
compartment. See the perlsec manpage for details about both these mechanisms.
Because Perl's regex engine is currently not re-entrant, interpolated
code may not invoke the regex engine either directly with m// or s///),
or indirectly with functions such as split.
(??{ code })-
WARNING: This extended regular expression feature is considered
highly experimental, and may be changed or deleted without notice.
A simplified version of the syntax may be introduced for commonly
used idioms.
This is a "postponed" regular subexpression. The code is evaluated
at run time, at the moment this subexpression may match. The result
of evaluation is considered as a regular expression and matched as
if it were inserted instead of this construct.
The code is not interpolated. As before, the rules to determine
where the code ends are currently somewhat convoluted.
The following pattern matches a parenthesized group:
$re = qr{
\(
(?:
(?> [^()]+ ) # Non-parens without backtracking
|
(??{ $re }) # Group with matching parens
)*
\)
}x;
Because perl's regex engine is not currently re-entrant, delayed
code may not invoke the regex engine either directly with m// or s///),
or indirectly with functions such as split.
(?>pattern)-
WARNING: This extended regular expression feature is considered
highly experimental, and may be changed or deleted without notice.
An "independent" subexpression, one which matches the substring
that a standalone pattern would match if anchored at the given
position, and it matches nothing other than this substring. This
construct is useful for optimizations of what would otherwise be
"eternal" matches, because it will not backtrack (see Backtracking).
It may also be useful in places where the "grab all you can, and do not
give anything back" semantic is desirable.
For example: ^(?>a*)ab will never match, since (?>a*)
(anchored at the beginning of string, as above) will match all
characters a at the beginning of string, leaving no a for
ab to match. In contrast, a*ab will match the same as a+b,
since the match of the subgroup a* is influenced by the following
group ab (see Backtracking). In particular, a* inside
a*ab will match fewer characters than a standalone a*, since
this makes the tail match.
An effect similar to (?>pattern) may be achieved by writing
(?=(pattern))\1. This matches the same substring as a standalone
a+, and the following \1 eats the matched string; it therefore
makes a zero-length assertion into an analogue of (?>...).
(The difference between these two constructs is that the second one
uses a capturing group, thus shifting ordinals of backreferences
in the rest of a regular expression.)
Consider this pattern:
m{ \(
(
[^()]+ # x+
|
\( [^()]* \)
)+
\)
}x
That will efficiently match a nonempty group with matching parentheses
two levels deep or less. However, if there is no such group, it
will take virtually forever on a long string. That's because there
are so many different ways to split a long string into several
substrings. This is what (.+)+ is doing, and (.+)+ is similar
to a subpattern of the above pattern. Consider how the pattern
above detects no-match on ((()aaaaaaaaaaaaaaaaaa in several
seconds, but that each extra letter doubles this time. This
exponential performance will make it appear that your program has
hung. However, a tiny change to this pattern
m{ \(
(
(?> [^()]+ ) # change x+ above to (?> x+ )
|
\( [^()]* \)
)+
\)
}x
which uses (?>...) matches exactly when the one above does (verifying
this yourself would be a productive exercise), but finishes in a fourth
the time when used on a similar string with 1000000 as. Be aware,
however, that this pattern currently triggers a warning message under
the use warnings pragma or -w switch saying it
"matches null string many times in regex".
On simple groups, such as the pattern (?> [^()]+ ), a comparable
effect may be achieved by negative look-ahead, as in [^()]+ (?! [^()] ).
This was only 4 times slower on a string with 1000000 as.
The "grab all you can, and do not give anything back" semantic is desirable
in many situations where on the first sight a simple ()* looks like
the correct solution. Suppose we parse text with comments being delimited
by # followed by some optional (horizontal) whitespace. Contrary to
its appearance, #[ \t]* is not the correct subexpression to match
the comment delimiter, because it may "give up" some whitespace if
the remainder of the pattern can be made to match that way. The correct
answer is either one of these:
(?>#[ \t]*)
#[ \t]*(?![ \t])
For example, to grab non-empty comments into $1, one should use either
one of these:
/ (?> \# [ \t]* ) ( .+ ) /x;
/ \# [ \t]* ( [^ \t] .* ) /x;
Which one you pick depends on which of these expressions better reflects
the above specification of comments.
(?(condition)yes-pattern|no-pattern)(?(condition)yes-pattern)-
WARNING: This extended regular expression feature is considered
highly experimental, and may be changed or deleted without notice.
Conditional expression. (condition) should be either an integer in
parentheses (which is valid if the corresponding pair of parentheses
matched), or look-ahead/look-behind/evaluate zero-width assertion.
For example:
m{ ( \( )?
[^()]+
(?(1) \) )
}x
matches a chunk of non-parentheses, possibly included in parentheses
themselves.
NOTE: This section presents an abstract approximation of regular
expression behavior. For a more rigorous (and complicated) view of
the rules involved in selecting a match among possible alternatives,
see Combining RE Pieces.
A fundamental feature of regular expression matching involves the
notion called backtracking, which is currently used (when needed)
by all regular non-possessive expression quantifiers, namely *, *?, +,
+?, {n,m}, and {n,m}?. Backtracking is often optimized
internally, but the general principle outlined here is valid.
For a regular expression to match, the entire regular expression must
match, not just part of it. So if the beginning of a pattern containing a
quantifier succeeds in a way that causes later parts in the pattern to
fail, the matching engine backs up and recalculates the beginning
part--that's why it's called backtracking.
Here is an example of backtracking: Let's say you want to find the
word following "foo" in the string "Food is on the foo table.":
$_ = "Food is on the foo table.";
if ( /\b(foo)\s+(\w+)/i ) {
print "$2 follows $1.\n";
}
When the match runs, the first part of the regular expression (\b(foo))
finds a possible match right at the beginning of the string, and loads up
$1 with "Foo". However, as soon as the matching engine sees that there's
no whitespace following the "Foo" that it had saved in $1, it realizes its
mistake and starts over again one character after where it had the
tentative match. This time it goes all the way until the next occurrence
of "foo". The complete regular expression matches this time, and you get
the expected output of "table follows foo."
Sometimes minimal matching can help a lot. Imagine you'd like to match
everything between "foo" and "bar". Initially, you write something
like this:
$_ = "The food is under the bar in the barn.";
if ( /foo(.*)bar/ ) {
print "got <$1>\n";
}
Which perhaps unexpectedly yields:
got <d is under the bar in the >
That's because .* was greedy, so you get everything between the
first "foo" and the last "bar". Here it's more effective
to use minimal matching to make sure you get the text between a "foo"
and the first "bar" thereafter.
if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
got <d is under the >
Here's another example. Let's say you'd like to match a number at the end
of a string, and you also want to keep the preceding part of the match.
So you write this:
$_ = "I have 2 numbers: 53147";
if ( /(.*)(\d*)/ ) {
print "Beginning is <$1>, number is <$2>.\n";
}
That won't work at all, because .* was greedy and gobbled up the
whole string. As \d* can match on an empty string the complete
regular expression matched successfully.
Beginning is <I have 2 numbers: 53147>, number is <>.
Here are some variants, most of which don't work:
$_ = "I have 2 numbers: 53147";
@pats = qw{
(.*)(\d*)
(.*)(\d+)
(.*?)(\d*)
(.*?)(\d+)
(.*)(\d+)$
(.*?)(\d+)$
(.*)\b(\d+)$
(.*\D)(\d+)$
};
for $pat (@pats) {
printf "%-12s ", $pat;
if ( /$pat/ ) {
print "<$1> <$2>\n";
} else {
print "FAIL\n";
}
}
That will print out:
(.*)(\d*) <I have 2 numbers: 53147> <>
(.*)(\d+) <I have 2 numbers: 5314> <7>
(.*?)(\d*) <> <>
(.*?)(\d+) <I have > <2>
(.*)(\d+)$ <I have 2 numbers: 5314> <7>
(.*?)(\d+)$ <I have 2 numbers: > <53147>
(.*)\b(\d+)$ <I have 2 numbers: > <53147>
(.*\D)(\d+)$ <I have 2 numbers: > <53147>
As you see, this can be a bit tricky. It's important to realize that a
regular expression is merely a set of assertions that gives a definition
of success. There may be 0, 1, or several different ways that the
definition might succeed against a particular string. And if there are
multiple ways it might succeed, you need to understand backtracking to
know which variety of success you will achieve.
When using look-ahead assertions and negations, this can all get even
trickier. Imagine you'd like to find a sequence of non-digits not
followed by "123". You might try to write that as
$_ = "ABC123";
if ( /^\D*(?!123)/ ) {
print "Yup, no 123 in $_\n";
}
But that isn't going to match; at least, not the way you're hoping. It
claims that there is no 123 in the string. Here's a clearer picture of
why that pattern matches, contrary to popular expectations:
$x |
